ASMB,R,L,C,Q
*     NAME:   .CLGN 
*     SOURCE: 92067-18088 
*     RELPC:  92067-16125 
*     PGMR:   G.L.M.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
      NAM .CLGN,7 92067-16125 REV.1903 780928 
* 
* 
* 
      ENT .CLGN 
* 
      EXT $DSCS,EXEC,$LGON
* 
* 
A     EQU 0 
B     EQU 1 
* 
* 
*  PURPOSE: PASS A SPECIAL REQUEST TO THE LOGON PROGRAM AND 
*           RETURN A CLASS NUMBER FOR INTEGERATION OF RESULT. 
* 
* 
*  CALLING SEQUENCE: (A)=ADDRESS OF BUFFER TO PASS
*                    (B)=LENGTH 
*                    JSB .CLGN
*                    DEC -CALL CODE FOR LOGON 
* 
*            RTN (A)-1= SESSION NOT INITIALIZED OR NOT INSTALLED
*            ELSE     = CLASS# TO FETCH RESULT
* 
* 
      SKP 
* 
* 
* 
.CLGN NOP 
      STB BUFF      ADDRESS 
      STA TLEN        LENGTH
      XLA $DSCS     FETCH DISC POOL POINTER (UP\DOWN FLAG)
      SSA           IF NEGATIVE 
      JMP ERR1        WE CAN'T CONTINUE 
* 
      XLA $LGON     FETCH LOGON CLASS # 
      SZA,RSS       IF NOT DEFINED
      JMP ERR1        SESSION NOT YET UP
* 
      IOR SAVC      . MAKE SURE THE CLASS # ISN'T RELEASED
      STA LGC       SAVE LOGON CLASS NUMBER 
* 
*  MAKE SURE LOGON EXISTS AND IS EXECUTING
* 
      JSB EXEC
      DEF EX.4
      DEF DS10
      DEF LOGON 
EX.4  EQU * 
      NOP           POSSIBLE ERROR CONDITION
      CPB "05"      IF SCO5 ERROR 
      JMP ERR1        DON'T GO ANY FURTHER
* 
*  GET CLASS # FOR RESPONSE FROM LOGON
* 
      CLA 
      STA CCLAS     FORCE ALLOCATION
* 
      JSB EXEC
      DEF EX1 
      DEF D18       CLASS WRITE 
      DEF NOP        LU 0 
      DEF * 
      DEF NOP           ZERO LENGTH TRANSFER
      DEF * 
      DEF * 
      DEF CCLAS           CLASS # RETURNED HERE 
EX1   EQU * 
* 
* 
* 
* 
*  ISSUE CLASS WRITE-READ TO LOGON
* 
* 
* 
      JSB EXEC
      DEF EX3 
      DEF DS20      NO-ABORT CLASS WRITE-READ 
      DEF NOP       LU 0
BUFF  NOP           BUFFER ADDR 
      DEF TLEN        LENGTH
      DEF CCLAS     COMMUNICATION CLASS FOR RETURN STATUS 
      DEF .CLGN,I   CALL CODE 
      DEF LGC       LOGON CLASS NUMBER
EX3   EQU * 
* 
      JMP ERR1      IF CLASS REQUEST REJECTED, BAD NEWS.
* 
* 
* 
*  MAKE SURE LOGON IS EXECUTING 
* 
* 
      JSB EXEC
      DEF EX4 
      DEF DS10      NO-ABORT SCHED, NO QUEUE OR WAIT
      DEF LOGON 
EX4   EQU * 
* 
      NOP           POSSIBLE ERROR RETURN 
* 
* 
      LDA CCLAS     RETURN COMMUNICATION CLASS
      IOR SAVC      SET SAVE CLASS BIT
      RSS 
ERR1  CCA           BAD STATE OF SESSION
      ISZ .CLGN     BUMP RTN
      JMP .CLGN,I 
* 
* 
LOGON ASC 3,LOGON 
DS10  OCT 100012
DS20  OCT 100024
NOP   NOP 
SAVC  OCT 20000 
CCLAS NOP 
TLEN  NOP 
LGC   NOP 
D18   DEC 18
D21   DEC 21
"05"  ASC 1,05
      END 
                                                                                              