ASMB,R,L,C    ** LOGLU - RETURNS LU FROM PROGRAM ID SEGMENT 
      HED -LOGLU - FIND LU THAT THIS PROGRAM ORIGINATED FROM. 
*     NAME:   LOGLU 
*     SOURCE: 92067-18064 
*     RELOC:  92067-16035 
*     PGMR:   C.M.M.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1978.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM LOGLU,7 92067-16035 REV.1826 780502 
      ENT LOGLU 
* 
*     ROUTINE TO FIND THE LOGICAL UNIT NUMBER THAT THIS 
*     PROGRAM ORIGINATED FROM.
*          CALLED AS FOLLOWS: 
* 
* LU = LOGLU(IDUMY)           JSB LOGLU 
*                             DEF *+2 
*                             DEF IDUMY 
* 
* 
*    LU = A REG = LU #     OF LU AT WHICH 'RU'  OR  'ON' WAS ENTERED. 
*                          OR IF SCHEDULED BY A FATHER, THE LU AT WHICH 
*                          THE FATHER WAS SCHEDULED.
*               = 1        IF PROGRAM SCHEDULED BY INTERUPT OR TIME LIST
*         B REG = ASCII LU #
*         IDUMY = 0  IF IN SESSION
*               = -1 IF NOT IN SESSION
* 
* 
LOGLU NOP           ENTRY 
      DLD LOGLU,I   GET RETURN ADDRESS & DUMMY ADDRESS
      STB DUMMY     SAVE DUMMY ADDRESS
      STA LOGLU     &RETURN ADDRESS 
      LDB XEQT      GET MY ID ADDRESS 
      ADB D14       INDEX TO TYPE  WORD 
      XLA B,I       GET THE TYPE
      AND D7
      CPA D1
      ADB DM4 
      ADB D18    CALCULATE SESSION WORD ADDRESS 
      XLA B,I      GET THE SESSION WORD 
      SZA,RSS       IF = 0 WE ARE NOT IN SESSION
      CCA           SO SET LU = -1
      SSA           ARE WE IN SESSION ? 
      CCB,RSS       NO
      CLB           YES 
      STB DUMMY,I   GIVE ANSWER TO CALLER 
* 
      SPC 1 
*************************************************************** 
*     SESSION MONITOR LU RETRIEVAL CODE TO BE INSERTED HERE   * 
*************************************************************** 
      SPC 1 
* 
      CMA,INA       MAKE LU POS 
      STA LU# 
* 
      CLB          NOW CONVERT TO ASCII 
      DIV D10 
      ALF,ALF 
      ADB A 
      ADB ASC00     B = ASCII LU #
      LDA LU#       A = BINARY LU # 
      JMP LOGLU,I   RETURN
* 
* 
* 
D1    DEC 1 
D7    DEC 7 
D14   DEC 14
D18   DEC 18
D10   DEC 10
D30   DEC 30
DM4   DEC -4
DUMMY NOP 
LU#   NOP 
ASC00 ASC 1,00
XEQT  EQU 1717B 
A     EQU 0 
B     EQU 1 
      END 
                                                                                                                                        