ASMB,R,L,C    ** IFTTY - SEE IF SPECIFIED LU IS INTERACTIVE.
      HED -IFTTY - DETERMINES IF SPECIFIED LU IS INTERACTIVE. 
*     NAME:   IFTTY 
*     SOURCE: 92067-18063 
*     RELOC:  PART OF 92067-16035 
*     PGMR:   C.M.M.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1978.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM IFTTY,7 92067-16035 REV.2013 800211 
      ENT IFTTY,.TTY
      EXT EXEC
* 
*     ROUTINE TO DETERMINE IF THE SPECIFIED LU IS INTERACTIVE 
*          CALLED AS FOLLOWS: 
* 
* IFLAG = IFTTY(LU)           JSB IFTTY 
*                             DEF *+2 
*                             DEF LU
* 
* 
* IFLAG = A REG = -1       IF THE LU IS INTERACTIVE 
*               =  0       IF THE LU IS NON-INTERACTIVE 
*         B REG = UPPER BYTE = DEVICE TYPE
*                 LOWER BYTE = SUBCHANNEL NUMBER
* 
* 
* 
.TTY  EQU * 
IFTTY NOP           ENTRY 
      DLD IFTTY,I   GET RETURN ADDRESS & LU#
      LDB B,I       GET THE LU #
      STA IFTTY     SAVE RETURN ADDRESS 
      STB ANLU#     AND LU #
      SZB,RSS       IF LU 0, THEN           *2013 DLS*
      JMP UNDEF      RETURN NON-INTERACTIVE.*2013 DLS*
* 
      JSB EXEC      SEE IF THE LU IS INTERACTIVE
      DEF *+6 
      DEF D13I      STATUS REQUEST
      DEF ANLU#     THE LU WE WANT THE INFO ABOUT 
      DEF YTEMP     EQT WORD 5 PLACED HERE
      DEF DTYPE     EQT WORD 4 PLACED HERE(NOT NEEDED)
      DEF ZTEMP     SUB CHANNEL IN LOWER 5 BIT HERE 
      JMP UNDEF     IT AIN'T EVEN AN LU !!!!  *2013 DLS*
* 
      LDA DTYPE     GET EQT WORD 4 AND         *2013 DLS* 
      AND B77        ISOLATE I-O SELECT CODE.  *2013 DLS* 
      SZA,RSS       IF LU ASSIGNED TO ZERO,    *2013 DLS* 
      JMP UNDEF      RETURN AS NON-INTERACTIVE.*2013 DLS* 
* 
      LDA YTEMP     GET EQT WORD 5
      AND MEQT      KEEP ONLY THE EQT TYPE FIELD
      LDB A         AND SAVE IT 
      LDA ZTEMP     GET THE SUBCHANNEL BITS 
      AND M37 
      STA ZTEMP 
      ADA B        CONFIGURE B REGISTER RETURN WORD 
      STA DTYPE 
      SZB,RSS       IF DVR 00 THEN
      JMP ITSIN     ITS INTERACTIVE 
      CPB M2400     IF DVR 05 THEN
      JMP DVR05     DO ONE MORE CHECK FOR SUB CHANNEL 
      CPB M3400     IS IT DVR07 ? 
      JMP DVR05     THEN DO DVR05 CHECK 
      JMP ITSNT     ELSE ITS NOT INTERACTIVE
* 
UNDEF CLB           CLEAR INDICATOR OF DEVICE   *2013 DLS*
      STB DTYPE      TYPE AND SUBCHANNEL.       *2013 DLS*
      JMP ITSNT     RETURN AS NON-INTERACTIVE.  *2013 DLS*
* 
DVR05 LDA ZTEMP     GET THE SUB CHANNEL # 
      SZA,RSS       IF  = 0 THEN ITS
ITSIN CCA,RSS       SET INTERACTIVE FLAG
ITSNT CLA           SET NON INTERACTIVE FLAG
      LDB DTYPE 
      JMP IFTTY,I   RETURN TO CALLER
* 
* 
D13I  OCT 100015
M2400 OCT 2400
M37   OCT 37
B77   OCT 77
M3400 OCT 3400
MEQT  OCT 37400 
ANLU# NOP 
DTYPE NOP 
YTEMP NOP 
ZTEMP NOP 
A     EQU 0 
B     EQU 1 
      END 
                                                  