ASMB,R,L,C
*     NAME:   DTTY
*     SOURCE: 92064-18076 
*     RELOC:  92064-16067 
*     PGMR:   G.L.M.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1977.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
      NAM DTTY,7  92064-16067  REV.1650  760524 
* 
*     DTTY/.TTY  DETERMINE IF THE REFERENCED LU IS ASSOCIATED 
*     WITH A INTERACTIVE DEVICE (DVR00 OR DVR05 SC 0).
* 
*     .TTY CALLING SEQUENCE:  
* 
*       JSB .TTY
*       DEF RTN 
*       DEF LU OF DEVICE TO BE CHECKED
* 
* 
*     DTTY CALLING SEQUENCE:
* 
*       LDA LU OF DEVICE TO BE CHECKED
*       JSB DTTY
* 
* 
*     COMMON RETURN 
* 
*     A=0 IF NOT INTERACTIVE
*     A#0 IF INTERACTIVE
* 
* 
* 
      EXT EXEC,.ENTR
      ENT DTTY,.TTY 
* 
* 
* 
LU    NOP 
.TTY  NOP 
      JSB .ENTR 
      DEF LU
      LDA .TTY
      STA DTTY
      LDA LU,I
      JMP DTTY2 
* 
DTTY  NOP 
DTTY2 SSA 
      CMA,INA 
      STA LU
* 
      JSB EXEC       REQUEST STATUS 
      DEF RT1 
      DEF .13 
      DEF LU
      DEF EQ5 
      DEF EQ4 
      DEF SPC 
* 
* 
RT1   LDA EQ5        CHECK FOR DVR00
      AND TYPE
      SZA,RSS 
      JMP GOOD       YEP--TAKE GOOD EXIT
* 
      ADA NDVR5      CHECK FOR DVR05
      SZA,RSS 
      JMP SBCNL      YEP--SO FAR SO GOOD--GO CHECK FOR SUB CHNL 0 
* 
BAD   CLA            TAKE FALSE EXIT
      JMP DTTY,I
* 
SBCNL LDA SPC        FETCH SUB CHNL 
      AND B77 
      SZA 
      JMP BAD        NOT ZERO 
GOOD  CLA,INA        ALL RIGHT--TAKE INTERACTIVE EXIT 
      JMP DTTY,I
* 
* 
* 
* 
SPC   NOP 
.13   DEC 13
EQ5   NOP 
EQ4   NOP 
TYPE  OCT 37400 
NDVR5 OCT -2400 
B77   OCT 77
* 
      END 
* 
                                    