/RIM LOADER.
/MODIFIED VERSION TO PRINT
/OCTAL ADDRESS/CONTENTS ON
/TELETYPE INSTEAD OF LOADING MEMORY.
/
*0
	RFC		/CLEAR BUFFER AND READ A CHAR
	JMP BEG+2	/JUMP INTO MAIN PROGRAM
BEG,	CLA		/CLEAR AC
	RRB		/GET CHAR INTO AC
	CLL RTL		/ROTATE CHANNEL 8 TO
	RTL		/BIT 0 OF AC
	SPA		/WAS IT SET (LEADER/TRAILER)?
	JMP BEG		/YES - LEADER/TRAILER - IGNORE
	RTL		/NO - ROTATE CHANNEL 7 TO LINK
	DCA TEMP	/SAVE WORD
	RRB		/READ ANOTHER CHAR
	TAD TEMP	/ADD IN OLD VALUE
	DCA TEMP	/SAVE WORD TO BE PRINTED
	SNL		/IS 12-BIT WORD IN AC AN ADDRESS?
	JMP CRLF	/NO - PRINT WORD, CR/LF
	JMS PROCT	/YES - PRINT WORD FOLLOWED BY /
	TAD ("/		/LOAD '/'
	TLS		/PRINT IT
	JMP BEG		/LOOP
CRLF,	JMS PROCT	/PRINT WORD
	TAD (215	/CAR RET
	TLS
	CLA
	TAD (212	/LINE FEED
	TLS
	JMP BEG		/LOOP
TEMP,	0
/
PROCT,	0		/ROUTINE TO PRINT (TEMP) IN OCTAL
	TAD TEMP	/GET CHAR
	RTL		/ROTATE 1ST DIG. INTO AC9-AC11
	RTL
	JMS DIGIT	/PRINT IT
	TAD TEMP	/GET NUMBER
	RTR		/ROTATE 2ND DIG. INTO AC9-AC11
	RTR
	RTR
	JMS DIGIT	/PRINT IT
	TAD TEMP
	RTR
	RAR
	JMS DIGIT	/PRINT 3RD DIGIT
	TAD TEMP
	JMS DIGIT	/PRINT 4TH DIGIT
	JMP I PROCT	/RETURN (AC CLEAR)
/
DIGIT,	0
	AND (7		/MASK OUT UPPER 9 BITS
	TAD (260	/CONVERT TO ASCII
	TLS		/PRINT DIGIT
	CLA		/CLEAR AC
	JMP I DIGIT	/RETURN
$