(NUMBER)

"PER BRINCH HANSEN

 INFORMATION SCIENCE
 CALIFORNIA INSTITUTE OF TECHNOLOGY

 UTILITY PROGRAMS FOR
 THE SOLO SYSTEM

 18 MAY 1975"


"###########
#  PREFIX  #
###########"


CONST NL = '(:10:)';   FF = '(:12:)';   CR = '(:13:)';   EM = '(:25:)';

CONST PAGELENGTH = 512;
TYPE PAGE = ARRAY (.1..PAGELENGTH.) OF CHAR;

CONST LINELENGTH = 132;
TYPE LINE = ARRAY (.1..LINELENGTH.) OF CHAR;

CONST IDLENGTH = 12;
TYPE IDENTIFIER = ARRAY (.1..IDLENGTH.) OF CHAR;

TYPE FILE = 1..2;

TYPE FILEKIND = (EMPTY, SCRATCH, ASCII, SEQCODE, CONCODE);

TYPE FILEATTR = RECORD
                  KIND: FILEKIND;
                  ADDR: INTEGER;
                  PROTECTED: BOOLEAN;
                  NOTUSED: ARRAY (.1..5.) OF INTEGER
                END;

TYPE IODEVICE =
  (TYPEDEVICE, DISKDEVICE, TAPEDEVICE, PRINTDEVICE, CARDDEVICE);

TYPE IOOPERATION = (INPUT, OUTPUT, MOVE, CONTROL);

TYPE IOARG = (WRITEEOF, REWIND, UPSPACE, BACKSPACE);

TYPE IORESULT =
  (COMPLETE, INTERVENTION, TRANSMISSION, FAILURE,
   ENDFILE, ENDMEDIUM, STARTMEDIUM);

TYPE IOPARAM = RECORD
                 OPERATION: IOOPERATION;
                 STATUS: IORESULT;
                 ARG: IOARG
               END;

TYPE TASKKIND = (INPUTTASK, JOBTASK, OUTPUTTASK);

TYPE ARGTAG =
  (NILTYPE, BOOLTYPE, INTTYPE, IDTYPE, PTRTYPE);

TYPE POINTER = @BOOLEAN;

TYPE ARGTYPE = RECORD
                 CASE TAG: ARGTAG OF
                   NILTYPE, BOOLTYPE: (BOOL: BOOLEAN);
                   INTTYPE: (INT: INTEGER);
                   IDTYPE: (ID: IDENTIFIER);
                   PTRTYPE: (PTR: POINTER)
               END;

CONST MAXARG = 10;
TYPE ARGLIST = ARRAY (.1..MAXARG.) OF ARGTYPE;

TYPE ARGSEQ = (INP, OUT);

TYPE PROGRESULT =
  (TERMINATED, OVERFLOW, POINTERERROR, RANGEERROR, VARIANTERROR,
   HEAPLIMIT, STACKLIMIT, CODELIMIT, TIMELIMIT, CALLERROR);

PROCEDURE READ(VAR C: CHAR);
PROCEDURE WRITE(C: CHAR);

PROCEDURE OPEN(F: FILE; ID: IDENTIFIER; VAR FOUND: BOOLEAN);
PROCEDURE CLOSE(F: FILE);
PROCEDURE GET(F: FILE; P: INTEGER; VAR BLOCK: UNIV PAGE);
PROCEDURE PUT(F: FILE; P: INTEGER; VAR BLOCK: UNIV PAGE);
FUNCTION LENGTH(F: FILE): INTEGER;

PROCEDURE MARK(VAR TOP: INTEGER);
PROCEDURE RELEASE(TOP: INTEGER);

PROCEDURE IDENTIFY(HEADER: LINE);
PROCEDURE ACCEPT(VAR C: CHAR);
PROCEDURE DISPLAY(C: CHAR);

PROCEDURE READPAGE(VAR BLOCK: UNIV PAGE; VAR EOF: BOOLEAN);
PROCEDURE WRITEPAGE(BLOCK: UNIV PAGE; EOF: BOOLEAN);
PROCEDURE READLINE(VAR TEXT: UNIV LINE);
PROCEDURE WRITELINE(TEXT: UNIV LINE);
PROCEDURE READARG(S: ARGSEQ; VAR ARG: ARGTYPE);
PROCEDURE WRITEARG(S: ARGSEQ; ARG: ARGTYPE);

PROCEDURE LOOKUP(ID: IDENTIFIER; VAR ATTR: FILEATTR; VAR FOUND: BOOLEAN);

PROCEDURE IOTRANSFER
  (DEVICE: IODEVICE; VAR PARAM: IOPARAM; VAR BLOCK: UNIV PAGE);

PROCEDURE IOMOVE(DEVICE: IODEVICE; VAR PARAM: IOPARAM);

FUNCTION TASK: TASKKIND;

PROCEDURE RUN(ID: IDENTIFIER; VAR PARAM: ARGLIST;
              VAR LINE: INTEGER; VAR RESULT: PROGRESULT);


PROGRAM P(VAR PARAM: ARGLIST);


"#########################
#  DISK(ID: IDENTIFIER)  #
#########################"


VAR OK: BOOLEAN; FILEID: IDENTIFIER; FILELENGTH: INTEGER;

PROCEDURE WRITETEXT(TEXT: LINE);
VAR I: INTEGER; C: CHAR;
BEGIN
  I:= 0;
  REPEAT
    I:= I + 1;
    C:= TEXT(.I.);
    DISPLAY(C);
  UNTIL C = NL;
END;

PROCEDURE INITIALIZE;
BEGIN
  IF TASK = INPUTTASK
    THEN IDENTIFY('DISKINPUT: (:10:)')
    ELSE IDENTIFY('DISKOUTPUT:(:10:)');
  FILEID:= PARAM(.2.).ID;
  OPEN(1, FILEID, OK);
  IF NOT OK THEN
    WRITETEXT('FILE UNKNOWN (:10:)');
END;

PROCEDURE RETURNLENGTH;
VAR ARG: ARGTYPE;
BEGIN
  IF FILEID = 'NEXT        ' THEN
  BEGIN
    WITH ARG DO
    BEGIN TAG:= INTTYPE; INT:= FILELENGTH END;
    WRITEARG(INP, ARG);
  END;
END;

PROCEDURE DISKINPUT;
VAR PAGENO: INTEGER; TEXT: PAGE;
BEGIN
  FILELENGTH:= LENGTH(1);
  FOR PAGENO:= 1 TO FILELENGTH DO
  BEGIN
    GET(1, PAGENO, TEXT);
    WRITEPAGE(TEXT, FALSE);
  END;
  WRITEPAGE(TEXT, TRUE);
END;

PROCEDURE DISKOUTPUT;
VAR PAGENO, MAXNO: INTEGER; TEXT: PAGE; EOF: BOOLEAN;
BEGIN
  PAGENO:= 0; MAXNO:= LENGTH(1);
  READPAGE(TEXT, EOF);
  WHILE NOT EOF & (PAGENO < MAXNO) DO
  BEGIN
    PAGENO:= PAGENO + 1;
    PUT(1, PAGENO, TEXT);
    READPAGE(TEXT, EOF);
  END;
  IF NOT EOF THEN
  BEGIN
    WRITETEXT('FILE LIMIT (:10:)');
    OK:= FALSE;
  END;
  FILELENGTH:= PAGENO;
  RETURNLENGTH;
END;

PROCEDURE TERMINATE;
BEGIN
  CLOSE(1);
  WITH PARAM(.1.) DO
  BEGIN TAG:= BOOLTYPE; BOOL:= OK END;
END;


BEGIN
  IF TASK <> JOBTASK THEN
  BEGIN
    INITIALIZE;
    IF TASK = INPUTTASK
      THEN DISKINPUT
      ELSE DISKOUTPUT;
    TERMINATE;
  END;
END.
                                        